/ *PROGRAM A0802
/ *DATE MAY 8.1972
/ *PROGRAMMER: DR. PHIL TAI, MCS, INTEL CORP.
/ *
	ORG 0 0
BEGIN,  LAI 0           /LOAD 0 TO AC
	OUT 10Q         /WRITE TO OUTPUT 0
	OUT 11o         /WRITE TO OUTPUT 1
	OUT 12O         /WRITE TO OUTPUT 2
	OUT 13q         /WRITE TO OUTPUT 3
	LBI 8           /LOAD 8 TO REG. B
	LCI 0           /LOAD 0 TO REG. C
	LHI 8           /LOAD 8 TO REG. H
	LLI 0           /LOAD 0 TO REG. L
LM1,    XRA             /CLEAR AC
LM2,    LMA             /LOAD AC TO MEMORY
	INL             /L = L + 1
	CPL             /AC - L
	JFZ LM2         /JUMP IF AC IS NOT ZERO
	INH             /H = H + 1
	LAI 12          /LOAD 12 TO AC
	CPH             /AC-H
	JFZ LM1         /JUMP IF AC IS NOT ZERO
	LHI 8
REPT4,  LAB             /LOAD REG. B TO AC
	OUT 10
REPT3,  LLC             /LOAD REG. C TO L 
	LAC             /LOAD REG. C TO AC
	OUT 13
	LAI 255         /LOAD 255 TO AC
	LMA             /LOAD AC TO MEMORY
	CPM             /AC - M
	JFZ ERROR       /JUMP IF AC IS NOT ZERO
REPT2,  LAH             /LOAD REG. H TO AC 
	OUT 10
REPT5,  XRA             /CLEAR AC
	INL             /L = L + 1
	CPL             /AC - L
	JTZ REPT1       /JUMP IF AC+0
	LAL             /LOAD REG. L TO AC
	OUT 11
	XRA             /CLEAR AC
	CPM             /AC-M
	JFZ ERROR       /JUMP IF AC IS NOT ZERO
	JMP REPT5
REPT1,  INH             /H = H + 1 
	LAI 12
	CPH
	JTZ CONT
	XRA
	CPM
	JFZ ERROR
	JMP REPT2
CONT,   LHB             /LOAD REG. B TO H 
	XRA
	INC             /C = C + 1
	CPC             /AC - C         
	JFZ REPT3
	INB             /B = B + 1
	LHB             /LOAD REG. B TO H
	LAI 12
	CPB             /AC-B 
	JFZ REPT4
	JMP BEGIN
ERROR,  LAI 240         /LOAD 240 TO AC
	ADB             /AC = AC+B
	OUT 10
	LAL             /LOAD REG. L TO AC 
	OUT 11
	LAM             /LOAD MEMORY TO AC 
	OUT 12
	LAC             /LOAD REG. C TO AC 
	OUT 13
	HLT
	END